--Tabela de Teste
CREATE TABLE Teste_BackupFULL
( cod BIGINT IDENTITY PRIMARY key,
  Dt_log DATETIME2 DEFAULT(GETDATE()),
  Descricao VARCHAR(8000))

--Gerando dados para que o Backup demore um pouco
INSERT INTO Teste_BackupFULL(Descricao)
SELECT REPLICATE('a',3000)

INSERT INTO Teste_BackupFULL(Descricao)
SELECT Descricao 
FROM Teste_BackupFULL
GO 22 --isso pode demorar bastante

CREATE NONCLUSTERED INDEX SK01_Teste_BackupFULL ON Teste_BackupFULL(Dt_log)

-- sp_spaceused Teste_BackupFULL

-- Loop que será utilizado para simular inserts na base durante a execução do Backup
-- Executar em outra conexão
WHILE 1=1
begin
	INSERT INTO Teste_BackupFULL(Descricao)
	SELECT REPLICATE('a',3000)
	WAITFOR DELAY '00:00:01'
END

--Executar em outra conexão
BACKUP DATABASE Teste_Backup
TO DISK = 'C:\Temp\Teste_Backup_Dados.bak'
WITH STATS = 1,INIT

--Conferir o horário de início e fim do backup
SELECT TOP 1 database_name, backup_start_date,B.backup_finish_date, datediff(mi,backup_start_date,backup_finish_date) [tempo (min)],
	  position,server_name,recovery_model, cast(backup_size/1024/1024 as numeric(15,2)) [Tamanho (MB)]
FROM msdb.dbo.backupset B
	  INNER JOIN msdb.dbo.backupmediafamily BF ON B.media_set_id = BF.media_set_id
where backup_start_date >= dateadd(hh, -24 ,getdate()  )
  and type in ('D')
ORDER BY backup_start_date desc

-- Conferir os dados 
SELECT TOP 5000 *
FROM Teste_Backup..Teste_BackupFULL
ORDER BY Dt_log DESC

--Excluindo a base
USE [master]
GO
ALTER DATABASE [Teste_Backup] SET  SINGLE_USER WITH ROLLBACK IMMEDIATE

DROP DATABASE [Teste_Backup]
GO

--Restore da base para ver até quando o SQL guardou dados
RESTORE DATABASE Teste_Backup
FROM DISK = 'C:\Temp\Teste_Backup_Dados.bak'
WITH STATS = 1
  
--Conferir novamente os valores com as querys acima